教程 Windows 通用服务端启动脚本

[Hengsterx]

Minecraft 服务端通用启动脚本 (对于Windows)
 v1.0​

---

@echo OFF

:: ------------------------------------------------------------
:: 全局环境配置
:: 如果不了解此bat的其他内容, 请不要修改除此块以外的任何代码.
:: 请直接修改变量的值, 不要修改变量名!
:: -----

:: 窗口标题 (尽量使用英文，以防乱码)
set TITLE=A Minecraft Server

:: 服务端核心的JAR名称 (无需.jar)
set JAR_NAME=core

:: Java路径 (如果为路径则需要双引号"", 如果为系统环境变量已配置Java则直接使用java, 无需双引号)
set JAVA_PATH=java

:: 是否自动重启 (true 或 false)
set AUTO_RESTART=true

:: 禁用用户图形界面 (true 或 false | 仅限支持用户图形界面的服务端版本)
set NOGUI=false

:: ------------------------------------------------------------

set /a RESTART_TIMES=0

:start
title %TITLE%

echo --- Global configuration ---
echo Title: %TITLE%
echo Jar name: %JAR_NAME%
echo Java path: %JAVA_PATH%
echo Auto restart: %AUTO_RESTART%
echo No GUI: %NOGUI%
echo ----------------------------

if %RESTART_TIMES% GTR 0 (
    echo Restart times: %RESTART_TIMES%
    echo ----------------------------
)

if "%NOGUI%"=="true" (
    set STARTUP_COMMAND=%JAVA_PATH% -Dfile.encoding=UTF-8 -jar %JAR_NAME%.jar -nogui
) else (
    set STARTUP_COMMAND=%JAVA_PATH% -Dfile.encoding=UTF-8 -jar %JAR_NAME%.jar
)

echo Final startup command: %STARTUP_COMMAND%
echo ----------------------------

%STARTUP_COMMAND%

echo Server has exited.
if "%AUTO_RESTART%"=="true" (
    echo Restarting in 5 seconds...
    timeout /t 5 >nul
    cls
    set /a RESTART_TIMES+=1
    echo Server restarting...
    goto start
) else (
    echo Press any key to exit...
    pause >nul
    exit
)

---

请注意: 请不要修改除“全局环境配置”块以外的其他代码。除非你知道你在干什么！

---

全局环境配置说明​

TITLE
Bat窗口的标题。请尽量使用英文命名，以防止乱码。

接受值: 字符串


JAR_NAME
服务端核心JAR的名称。无需带.jar。

接受值: 字符串


JAVA_PATH
你的Java路径。如果你已经在系统环境变量中配置Java，那么请直接填写 java，不需要带双引号。
如果没有，则填写Java的路径，需要带双引号。

接受值: 字符串


AUTO_RESTART
是否在服务器关闭后自动重启（5秒后）

接受值: 伪Boolean（字符串）


NOGUI
是否禁用Minecraft Server的用户图形界面。仅支持支持用户图形界面的Minecraft Server版本。
非Bukkit等服务端服务器请不要启用此选项，否则可能会导致意外情况。

接受值: 伪Boolean（字符串）

---

使用方法​

在开始之前请确保文件资源管理器已开启显示文件后缀。具体方法请自行查找。

• 在服务器根目录下新建任意文件，并连带后缀一起重命名为 "任意名称.bat"。​
• 右键该文件，点击“编辑”。​
• 将本文章上方提供的bat代码粘贴进去。​
• 参考上文内容修改 “全局环境配置”。​
• 保存并启动服务器。大功告成！​

或者你也可以直接下载下方提供的文件。

---

文件下载
由于论坛无法上传.bat文件后缀的文件，因此将其打包为zip文件。请自行解压。

bat.zip [点击下载]​

---

感谢阅读本篇文章。如果你认为该bat文件中存在任何错误或异议，
欢迎在评论区中提出。​

 

[ice]

可以的~